http://jar.yosephine.com/ Scripts and stuff I en-us Nucleus CMS v3.32 � Weblog http://backend.userland.com/rss http://jar.yosephine.com//nucleus/nucleus2.gif http://jar.yosephine.com/ http://jar.yosephine.com/index.php?itemid=25
Today i will post some Christmas spirit for all you system admins to share in your network.

Since last Christmas we have had a special script called from within our logonscript. This special script will change the wallpaper for the users to a random wallpaper from a set of Christmas wallpapers on our server. The script changes the wallpaper only during December. After that it will change the wallpaper back to whatever it was before the change. As this script is called every time the user logs on it will change the wallpaper once for every logon. The change will not be visible to the user immediately, but it will show upon the next logon. This is because Windows has already loaded the wallpaper setting when the script is run, so the change always comes one logon later. The nice thing with this script is that it changes the background upon every logon during December, so users will be presented with various nice Christmas wallpapers. And when the new year comes, the original wallpaper of the user is restored. The script saves the original wallpaper in a file so it can restore it later. The script is not very nicely written, as all this has been done on my own time.
The script works both on Windows XP and Windows 7.
For you to be able to use this in your organization or on your personal Windows computer you will need to edit the following:

The strBackupFile variable. Currently it points to "c:\temp\wallpaper_username.bak". I have chosen to save the user's original wallpaper setting in a file called c:\temp\wallpaper_username.bak, in which the "username" will be changed to the user's username. So if my username is Frank the original wallpaper setting will be saved in a file called c:\temp\wallpaper_Frank.bak. If you wish to save the setting somewhere else you need to edit this text to something else.

The strWPLocation specifies the UNC path to the folder where you have all your nice Christmas wallpapers stored. Users should have appropriate access to this folder to be able to apply the wallpapers. The wallpapers need to be named 1.bmp, 2.bmp, 3.bmp... for this script to work. If you wish to use jpg, png or something else you will need to do a find/replace of all the ".bmp"-strings in the script.

The intWallpapers should be changed to the number of wallpapers you have in the shared folder. The script uses a crude randomizing function to randomly select any of the wallpapers in the folder.

Once you have set these variables to suit your environment and need you are ready to go.
As I mentioned earlier we call this script from the logon script. you may run it manually or whatever. Once you run it nothing seems to happen, but you will find the .bak file in the c:\temp folder and on next reboot your background has changed!

Happy Christmas!

Option Explicit

Dim objReg, objFSO, objFolder, objFile, objShell
Dim strComputer, strKeyPath, strValue, variable, strBackupFile, strWPLocation, intWallpapers
const HKEY_CURRENT_USER = &H80000001
const ForWriting = 2
const ForReading = 1

strComputer = "."
Set objReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\default:StdRegProv")
Set objFSO = CreateObject("Scripting.FileSystemObject")
strKeyPath = "Control Panel\Desktop"
strBackupFile = "c:\temp\wallpaper_" & EnvString("username") & ".bak"
strWPLocation = "\\server\share\Christmaswallpapers\"
intWallpapers = 17

'Check if it's Christmas:
If DatePart("m",now) = 12 Then
'Wscript.Echo "It's Christmas."
'Check if wallpaper has already been changed:
If not objFSO.FileExists(strBackupFile) Then
'Wscript.Echo "Wallpaper has not been changed."
'Get current wallpaper:
objReg.GetStringValue HKEY_CURRENT_USER, strKeyPath, "Wallpaper", strValue
'Wscript.Echo "Current wallpaper is " & strValue

'Save the current wallpaper setting to a file:
'Wscript.Echo "Saving current wallpaper setting."
On Error Resume Next
Set objFile = objFSO.OpenTextFile(strBackupFile, ForWriting, True)
If Err.Number Then
Wscript.Quit
End If
On Error GoTo 0
objFile.WriteLine strValue
objFile.Close

'Change the wallpaper to Christmas:
'Wscript.Echo "Changing wallpaper."
Randomize
objReg.SetStringValue HKEY_CURRENT_USER, strKeyPath, "Wallpaper", (int(intWallpapers*Rnd+1)) & ".bmp"
Else
'Wallpaper has been changed, but it's still Christmas, so change to another Christmasy wallpaper!
'Wscript.Echo "Changing wallpaper."
Randomize
objReg.SetStringValue HKEY_CURRENT_USER, strKeyPath, "Wallpaper", (int(intWallpapers*Rnd+1)) & ".bmp"

End If

Else
'Wscript.Echo "It's NOT Christmas."
'Check if wallpaper has already been changed:
If objFSO.FileExists(strBackupFile) Then
'Wscript.Echo "Wallpaper is still Christmas."
'Change wallpaper back to original:
'Wscript.Echo "Changing back wallpaper to original."
Set objFile = objFSO.OpenTextFile(strBackupFile) & ".bak", ForReading, True)
strValue = objFile.Readline
objReg.SetStringValue HKEY_CURRENT_USER, strKeyPath, "Wallpaper", strValue
objFile.Close

'Delete wallpaper backup file:
'Wscript.Echo "Deleting wallpaper setting file"
objFSO.DeleteFile(strBackupFile)
End If
End If



Function EnvString(variable)
'This function returns a particular environment variable’s value.
' for example, if you use EnvString("username"), it would return
' the value of %username%.
set objShell = WScript.CreateObject( "WScript.Shell" )
variable = "%" & variable & "%"
EnvString = objShell.ExpandEnvironmentStrings(variable)
Set objShell = Nothing
End Function
]]> General http://jar.yosephine.com/index.php?itemid=25 Wed, 30 Nov 2011 09:08:10 -0500 http://jar.yosephine.com/index.php?itemid=23 The thing that worries me, however, is the fact that so many password guessing attacks are being made all the time, and the SSHD itself doesn't provide an adequate protection against these. I can limit the amount of failed logon attempts before the server closes the line, but the attacker can just reconnect and try again. I can naturally also make sure that I don't permit root logon and restrict which accounts are allowed to log on remotely. Also, I could allow only certain hosts to connect, but this doesn't work either, as I often need to access my computer from whatever computer.
With thousands of script kiddies hammering my box hour after hour I'm not comfortable with only the above security measures.

I want to be able to block computers that have performed several unsuccessful logon attempts within a short time frame. In other words, I want to block attacks like these:

Invalid user apache from 79.29.80.124
input_userauth_request: invalid user apache
Failed password for invalid user apache from 79.29.80.124 port 50074 ssh2
Received disconnect from 79.29.80.124: 11: Bye Bye
Invalid user root from 79.29.80.124
input_userauth_request: invalid user root
Failed password for invalid user root from 79.29.80.124 port 50901 ssh2
Received disconnect from 79.29.80.124: 11: Bye Bye
Invalid user root from 79.29.80.124
input_userauth_request: invalid user root
Failed password for invalid user root from 79.29.80.124 port 50915 ssh2
Received disconnect from 79.29.80.124: 11: Bye Bye
Invalid user network from 79.29.80.124
input_userauth_request: invalid user network
Failed password for invalid user network from 79.29.80.124 port 52613 ssh2
...

So I wrote a script!

This is just a beginning of something that could prove useful. The script is designed to be run every hour, ten minutes, whatever, and reads the sshd log and checks for failed logon attempts. The script employs a threshold and any IP that has a failed logon attempt count above the threshold will be blocked from accessing the server. The blocking is performed by adding a blocking rule to the Windows firewall. The script currently never removes any of these rules, so they might build up. Maybe in the future I will enhance the script to employ a method for removing rules over a certain age.
I put the script to run every hour in my Task Scheduler.
Option Explicit
Dim intSize, i, intTreshold
Dim strTimestamp, strRunning, strServiceName, strComputer, strLogPath, strLogName, strLine
Dim objWMIService, colListOfServices, objService, objState
Dim colState, objFSO, objTextFile, objShell, objWshScriptExec
Dim boolMatch
Dim arrLine
Dim arrIPList(), arrIPList2()

Const ForReading = 1

strComputer = "."

'Block IP if failed logon attempts is more than the number below:
intTreshold = 10

'Path and filename to sshd.log:
strLogPath = "C:\Cygwin\var\log\"
strLogName = "sshd.log"

'Enter name of sshd service here:
strServiceName = "sshd"

intSize = 0


strTimestamp = DatePart("yyyy",Now) _
& Right("0" & DatePart("m",Now), 2) _
& Right("0" & DatePart("d",Now), 2) _
& Right("0" & DatePart("h",Now), 2) _
& Right("0" & DatePart("n",Now), 2)

'Stop service in order to release file lock on log file:
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" &

strComputer & "\root\cimv2")
Set colListOfServices = objWMIService.ExecQuery ("Select * from Win32_Service Where

Name = '" & strServiceName & "'")
For Each objService in colListOfServices
objService.StopService()
strRunning = 1
do while (strRunning = 1)
Wscript.sleep 5000
Set colState = objWMIService.ExecQuery ("Select * from Win32_Service

Where Name = '" & strServiceName & "'")
for each objState in colState
Wscript.Echo objState.DisplayName & VbTab & objState.State
if (objState.State = "Stopped") Then
strRunning=0
end if
Next
Loop
Next

'rename log file:
Set objFSO = CreateObject("Scripting.FileSystemObject")
objFSO.MoveFile strLogPath & strLogName , strLogPath & strTimestamp & ".log"

'Start service:
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" &

strComputer & "\root\cimv2")
Set colListOfServices = objWMIService.ExecQuery ("Select * from Win32_Service Where

Name = '" & strServiceName & "'")
For Each objService in colListOfServices
objService.StartService()
strRunning = 0
do while (strRunning = 0)
Wscript.sleep 5000
Set colState = objWMIService.ExecQuery ("Select * from Win32_Service

Where Name = '" & strServiceName & "'")
for each objState in colState
Wscript.Echo objState.DisplayName & VbTab & objState.State
if (objState.State = "Running") Then
strRunning=1
end if
Next
Loop
Next

'Parse log file for failed logon attempts and put IP addresses & attempt count in arrays:
Set objTextFile = objFSO.OpenTextFile(strLogPath & strTimestamp & ".log", ForReading)
ReDim Preserve arrIPList(intSize)
ReDim Preserve arrIPList2(intSize)
Do Until objTextFile.AtEndOfStream
strLine = objTextFile.ReadLine
if instr(strLine,"Failed password for") <> 0 Then
arrLine = Split(Replace(Replace(strLine," invalid user ",""),"Failed password for","")," ")
boolMatch = 0
For i = 0 to intSize
If arrLine(2) = arrIPList(i) Then
boolMatch = 1
arrIPList2(i) = arrIPList2(i) + 1
End if
Next
If boolMatch = 0 Then
intSize = intSize + 1
ReDim Preserve arrIPList(intSize)
ReDim Preserve arrIPList2(intSize)
arrIPList(intSize) = arrLine(2)
arrIPList2(intSize) = 1
End If
End If
Loop

Set objShell = CreateObject("WScript.Shell")
For i=0 to intSize
If arrIPList2(i) > intTreshold Then
Set objWshScriptExec = objShell.Exec("netsh advfirewall firewall add rule name=SSHBLOCKER_" & strTimestamp & " dir=in action=block remoteip=" & arrIPList(i))
End If
Next ]]> General http://jar.yosephine.com/index.php?itemid=23 Wed, 27 Oct 2010 07:52:23 -0400 http://jar.yosephine.com/index.php?itemid=20 I happen to work at such a place. As we have about 1500 computers, most of which need to have JRE installed, there's a lot of work keeping the JRE's on the workstations up to date. Even though we have a workstation management system for deploying the new Java it's a lot of work. To ease the burden of keeping the JRE environment up to date I made a simple script to remove all old versions of Java and install the new veresion.
The script checks what version(s) of Java is installed. It then removes all versions, except the most recent version. If the most recent version isn't installed it will install it. Furthermore, the script will copy the deployment.config file to the workstation. This file points the Java installation on the workstation to use settings from a central settings file. This might be useful in a corporate environment.
Please click on "Read more..." to read more :)The script will need administrative privileges to work. Also, the location of the JRE installer file must be a trusted location (in Internet Options). Otherwise the client will get the annoying "Open file security warning" dialog box.

The script looks somewhat like this:
*----CUT HERE---*
Option Explicit
Dim msiObject, msiProduct, strProdList, strProdInfo, msiProdVersion,appName1, appName2, InstallerPath
Dim CommandShell, cmdline, strDontUninstallThis, boolNewJavaExists, fso, objShell, variable, newfolder, ConfigFile
Const msiInstallStateDefault = 5

appName1 = "java" 'Application name (or part of name) to search for and uninstall.
appName2 = "j2se" 'Name of another application to search for and uninstall (some old java versions are shown in Add/remove programs as j2se)
strDontUninstallThis = "java(tm) 6 update 18" 'Here we put the name of the version that should NOT be uninstalled.
InstallerPath = "\\Servername\sharename\jre-6u18-windows-i586-s.exe" 'Change this to reflect the path where you have saved the JRE installer file.
ConfigFile = "\\servername\sharename\deployment.config" 'Change this to reflect the path where you have saved the deployment.config file.
boolNewJavaExists = False

strProdList = ""
Set msiObject = Wscript.CreateObject("WindowsInstaller.Installer")

For Each msiProduct In msiObject.Products
If InStr(LCase(msiObject.ProductInfo(msiProduct, "ProductName")), LCase(appName1)) Then
If not (LCase(msiObject.ProductInfo(msiProduct, "ProductName")) = LCase(strDontUninstallThis)) Then
set CommandShell = createobject("wscript.shell")
cmdline = "msiexec /X " & msiProduct & " /qn"
CommandShell.run cmdline, 1, true
Else
boolNewJavaExists = True
End If
ElseIf InStr(LCase(msiObject.ProductInfo(msiProduct, "ProductName")), LCase(appName2)) Then
If not (LCase(msiObject.ProductInfo(msiProduct, "ProductName")) = LCase(strDontUninstallThis)) Then
set CommandShell = createobject("wscript.shell")
cmdline = "msiexec /X " & msiProduct & " /qn"
CommandShell.run cmdline, 1, true
Else
boolNewJavaExists = True
End If

End If
Next

If (boolNewJavaExists = False) Then
set CommandShell = createobject("wscript.shell")
cmdline = Chr(34) & InstallerPath & Chr(34) & " /s AgreeToLicense=YES IEXPLORER=1 MOZILLA=1 REBOOT=Suppress JAVAUPDATE=0"
CommandShell.run cmdline, 1, true
End If

set fso=CreateObject("Scripting.FileSystemObject")
If fso.FileExists(ConfigFile) Then
If not fso.FolderExists(EnvString("windir") & "\sun\") Then
newfolder = fso.CreateFolder(EnvString("windir") & "\sun\")
End IF
If not fso.FolderExists(EnvString("windir") & "\sun\java\") Then
newfolder = fso.CreateFolder(EnvString("windir") & "\sun\java\")
End IF
If not fso.FolderExists(EnvString("windir") & "\sun\java\deployment\") Then
newfolder = fso.CreateFolder(EnvString("windir") & "\sun\java\deployment\")
End IF
fso.CopyFile ConfigFile, EnvString("windir") & "\sun\java\deployment\"
End If

Function EnvString(variable)
'This function returns a particular environment variable’s value.
' for example, if you use EnvString("username"), it would return
' the value of %username%.
set objShell = WScript.CreateObject( "WScript.Shell" )
variable = "%" & variable & "%"
EnvString = objShell.ExpandEnvironmentStrings(variable)
Set objShell = Nothing
End Function
*----CUT HERE---*

In addition to the script you will need the JRE installer, which can be downloaded from Sun's website.

Also, you will need to create a deployment.config file, which could look somewhat like this:

*----CUT HERE---*
deployment.system.config=file:\\\\Servername\\sharename\\deployment.properties
deployment.system.config.mandatory=FALSE
*----CUT HERE---*

Finally you will need a deployment.properties file, which you should save on some server share. The file might look something like this:

*----CUT HERE---*
deployment.javaws.shortcut=NEVER
deployment.javaws.autodownload=NEVER
deployment.javaws.autodownload.locked
deployment.cache.max.size = 200
*----CUT HERE---*

You may save all files in the same network share. Just make sure it's readable from the computers. The script can be run locally on each workstation e.g. using some workstation management system. You can also run it remotely e.g. using psexec.exe.]]> General http://jar.yosephine.com/index.php?itemid=20 Mon, 1 Feb 2010 02:53:35 -0500 http://jar.yosephine.com/index.php?itemid=18
The script uses w3sockets (socketreg.exe & socket.dll) from http://www.dimac.net. I won't post those files here, but you can download them from here.

Also, the script uses Microsoft's SMS sender for sending the SMS messages using a mobile phone connected to the computer that runs the script. The SMS sender program can be found here.

The SMS sender program is kind of problematic. When you send an SMS it will throw a notification on the screen. I've used pskill.exe (part of the pstools, available here) to kill the SMS sender program and its notifications.

And finally, the script itself is shown below...

'This script sends e-mail using SMTP, and then checks that the messages have arrived in the Excgange server mailbox using POP3.
'The purpose of the script is to monitor SMTP mail flow and alert if there is a problem in the mail flow.
'The script is dependent upon the socket.dll, which should be registered on the server (by running SocketReg.exe).
'The required files should be kept in the same dir as this script, in order to be available.
'This script also utilizes Microsoft's free smssender.exe to send alerts using a mobile phone connected to the computer.
'Also pskill.exe is used to kill the smssender.exe's notification.

'The following variables may be changed:
arrSMTPServers = array("SERVER1", "SERVER2") 'Put your servers here
intSMTPPort = 25 'Set the port to use for sending SMTP mail
strFromAddr = "youraddress@yourdomain.com" 'Set the sender address for the messages
strToAddr = "destinationaddress@yourdomain.com" 'Set the recipient address for the messages
strPOPServer = "popserver.yourdomain.com" 'Set the POP server
intPOPPort = 110 'Set the POP server port
strSMSSender = "c:\Program files\Microsoft SMS Sender\smssender.exe" 'Path to smssender.exe
strPhoneNumber = "5551234" 'Phone number to send alert messages to
strPSKill = "c:\temp\pskill.exe" 'Path to pskill.exe
strExpectedGreeting = "Microsoft Exchange" 'Expected greeting text of POP server
strPOPUser = "username" 'Username for the POP mailbox
strPOPPass = "password" 'Password for the POP mailbox

'Do not change anything below this line!
'---------------------------------------

Dim arrID() 'Array, containing the ID's for the messages to send.
On Error Resume Next
arrPath = Split(strSMSSender, "\")
strSMSexe = arrPath(Ubound(arrPath))

For i=0 to Ubound(arrSMTPServers)
'Generate ID's for the messages to send:
ReDim Preserve arrID(i)
arrID(i) = fGenerateID
'Send message:
subSendMail arrSMTPServers(i), intSMTPPort, strFromAddr, strToAddr, arrID(i), arrID(i)
Next

'Sleep for a while to allow time for the messages to be scanned and delivered:
Wscript.sleep 20000

For i=0 to Ubound(arrSMTPServers)
'Read mailbox, and search for our messages:
If fReadPOPMsgs (arrID(i), strPOPServer, intPOPPort, strExpectedGreeting, strPOPUser, strPOPPass) = 1 Then
Wscript.echo "Inbound SMTP route through " & arrSMTPServers(i) & " is OK!"
Else
Wscript.echo "Inbound SMTP route through " & arrSMTPServers(i) & " is DOWN!"
Set objShell = WScript.CreateObject("WScript.Shell")
objShell.Run (Chr(34) & strSMSSender & Chr(34) & " /p:" & strPhoneNumber & " /m:" & Chr(34) & "Inbound SMTP route through " & arrSMTPServers(i) & " is DOWN!" & Chr(34)),0
wscript.sleep 30000
objShell.Run (Chr(34) & strPSKill & Chr(34) & " " & strSMSexe)
End If
Next

fDelPOPMsgs strPOPServer, intPOPPort, strExpectedGreeting, strPOPUser, strPOPPass









'***************** subSendMail() **********************
Sub subSendMail(server, port, sender, recipient, subject, body)
Set objEmail = CreateObject("CDO.Message")
objEmail.From = sender
objEmail.To = recipient
objEmail.Subject = subject
objEmail.Textbody = body
objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = server
objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = port
objEmail.Configuration.Fields.Update
objEmail.Send
End Sub

'***************** fGenerateID() **********************
Function fGenerateID()
Randomize
b = 0
ID = ""
Do while b <= 40
ID = ID & Int(10 * Rnd)
b = b + 1
Loop
fGenerateID = ID
End Function



'***************** fReadPOPMsgs() **********************
Function fReadPOPMsgs(identifier, strPOPServer, intPOPPort, strExpectedGreeting, strPOPUser, strPOPPass)
Dim oSocket, iErr, sSocketText
sSocketText = ""
a = 1
strStat = ""
Set oSocket = CreateObject("Socket.TCP")
oSocket.DoTelnetEmulation = True
oSocket.TelnetEmulation = "TTY"
oSocket.Host = strPOPServer & ":" & intPOPPort
On Error Resume Next
oSocket.Open
iErr = Err.Number
If iErr <> 0 Then
fReadPOPMsgs = 0
Exit Function
End If
sSocketText = oSocket.GetLine
If InStr(sSocketText, strExpectedGreeting) = 0 Then WScript.Echo sSocketText

oSocket.SendLine "user " & strPOPUser
sSocketText = oSocket.GetLine
If InStr(sSocketText,"OK") = 0 Then WScript.Echo sSocketText

oSocket.SendLine "pass " & strPOPPass
sSocketText = oSocket.GetLine
If InStr(sSocketText,"User successfully logged on") = 0 Then WScript.Echo sSocketText

oSocket.SendLine "stat"
sSocketText = oSocket.GetLine
strStat = sSocketText
arrStat = Split(strStat, " ")

Do while Int(arrStat(1)) >= a
sSocketText = ""
oSocket.SendLine "retr " & a
Do while sSocketText <> "."
sSocketText = oSocket.GetLine
If InStr(sSocketText, identifier) <> 0 Then fReadPOPMsgs = 1
'WScript.Echo sSocketText
Loop
a = a + 1
Loop
oSocket.SendLine "quit"



oSocket.Close
On Error GoTo 0
'fReadPOPMsgs = 0

End Function

'***************** fDelPOPMsgs() **********************
Function fDelPOPMsgs(strPOPServer, intPOPPort, strExpectedGreeting, strPOPUser, strPOPPass)
Dim oSocket, iErr, sSocketText
sSocketText = ""
a = 1
strStat = ""
Set oSocket = CreateObject("Socket.TCP")
oSocket.DoTelnetEmulation = True
oSocket.TelnetEmulation = "TTY"
oSocket.Host = strPOPServer & ":" & intPOPPort
On Error Resume Next
oSocket.Open
iErr = Err.Number
If iErr <> 0 Then
fReadPOPMsgs = 0
Exit Function
End If
sSocketText = oSocket.GetLine
If InStr(sSocketText, strExpectedGreeting) = 0 Then WScript.Echo sSocketText

oSocket.SendLine "user " & strPOPUser
sSocketText = oSocket.GetLine
If InStr(sSocketText,"OK") = 0 Then WScript.Echo sSocketText

oSocket.SendLine "pass " & strPOPPass
sSocketText = oSocket.GetLine
If InStr(sSocketText,"User successfully logged on") = 0 Then WScript.Echo sSocketText

oSocket.SendLine "stat"
sSocketText = oSocket.GetLine
strStat = sSocketText
arrStat = Split(strStat, " ")
a=1
Do while Int(arrStat(1)) >= a
sSocketText = ""
oSocket.SendLine "dele " & a
sSocketText = oSocket.GetLine
' wscript.echo sSocketText
a = a + 1
Loop
oSocket.SendLine "quit"



oSocket.Close
On Error GoTo 0
fDelPOPMsgs = 0

End Function]]> General http://jar.yosephine.com/index.php?itemid=18 Thu, 10 Sep 2009 07:02:44 -0400 http://jar.yosephine.com/index.php?itemid=16
With 6000+ spams I figured it was best to just bulk-erase them all. Sorry for removing all nice comments as well.

For the time being the comment-section is closed :(]]> General http://jar.yosephine.com/index.php?itemid=16 Sun, 26 Jul 2009 18:13:51 -0400 http://jar.yosephine.com/index.php?itemid=14 here.

I've created a small and simple helpdesk application for our users in just a couple of hours. The hta does some basic diagnostics (Checking if the computer is on the network, checking that e-mail servers are available, checking CPU load, etc.), shows basic computer information (Computer name, make, model, memory, hard drive, serial number etc), and allows the user to send support requests to the support team. The nice thing with this method of sending support requests is that the hta can automatically add some relevant information to the support request (such as computer name and IP address), that the user doesn't necessarily understand to add themselves.

I may be posting the hta here if someone requests it, and more importantly, if I have the time to tidy it up a bit. For now the application is in English only, but I just might add different languages (Swedish, Finnish, German). ]]> General http://jar.yosephine.com/index.php?itemid=14 Fri, 29 May 2009 09:47:13 -0400 http://jar.yosephine.com/index.php?itemid=12
Well, anyway I should probably start investigating how I can get some publicity for my fine blog. The only thing is that I don't find that very interesting.

A quick search on one of the leading web search engines led me to some kind of link exchange program, which can be found here:
SubmitLinksFree.com - the high quality Links Directory for webmasters.

Add Your Link - Web Directory. Add your link today.

-Sorry, I had to include those links to be allowed to submit my link to the site. Let's see if it helps. I'm expecting to get numerous hits within the next 24 hours ;)]]> General http://jar.yosephine.com/index.php?itemid=12 Thu, 28 May 2009 15:00:31 -0400 http://jar.yosephine.com/index.php?itemid=10
The script works as follows:
First you need to make a file containing a list of old queues and their corresponding new queues. Let the file be named filename.txt in this example. Here's what filename.txt could look like:

\\OldServer\OldPrinterQueueName,\\NewServer\NewPrinterQueueName
\\OldServer\AnotherOldQueue,\\NewServer\AnotherNewQueue
\\AnotherOldServer\AThirdQueue,\\AnotherNewServer\AThirdQueue

As you probably can see, each line comprises an old queue and a new queue, separated by a comma. That's all. You may make the list as long as you want as long as each line contains just this comma-separated pair of printer queues. No comments, no other text is allowed, just the comma-separated pairs of queues, one pair per line.

Then you need to edit the script and insert the full UNC path of the file you just created. If you named the file "filename.txt", saved it on a share called "ShareName" on a server, named "Server", then you would enter "\\Server\ShareName\FileName.txt" as the value of the strFile variable in the script.

Finally you should make sure this script runs for each user in your environment. This can be done e.g. by calling it from the logon script. As the script might take some time to run you might want to make sure it runs only once for each user. This, in turn, may be accomplished e.g. by adding a few lines in your users' logon script(s), checking if a certain file exists in the user's profile. If the file exists, the logon script will skip calling the printer change script. If the file doesn't exist the logon script should call the printer change script and create this certain file in the user's profile to avoid that the printer change script is run the next time the user logs on.

Ok, that's probably all you need to know about the script. Here's the script code. You may use it free of charge as long as I'm given the appropriate credit. You may also change it as you wish, but you may not remove my name from it.


' Script that changes the user's printer(s) to other(s) printer(s) according to a csv list of printers.
' The list of printers should contain comma separated printer pairs, one pair at each line, like this:
' \\server1\printer1,\\server2\printer2
' where \\server1\printer1 is the printer that shall be replaced,
' and \\server2\printer2 is the printer that shall replace the beforementioned printer.
' The script can be called from a e.g. the logon script and the script can replace several different printers.
' Just add more lines to the list of printers and the script will go through them all.
' The script also notes which printer is the default printer and sets the replacing printer as default printer.
' Created by Dennis Nyholm 23.7.2008

'Fill in the filename of the list of printers here:
strFile = "\\servername\sharename\filename.txt"

Const ForReading = 1
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile(strFile, ForReading)
Do Until objTextFile.AtEndOfStream
strLine = objTextFile.Readline
arrprt = Split(strLine, ",")
Sourceprt = arrprt(0)
Destprt = arrprt(1)
'Wscript.Echo Sourceprt & " => " & Destprt
strComputer = "."
'Set error handling on:
'On Error Resume Next
Set objNetwork = CreateObject("Wscript.Network")

Set objWMIService = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colInstalledPrinters = objWMIService.ExecQuery _
("SELECT * FROM Win32_Printer")
For Each objPrinter in colInstalledPrinters
'Wscript.Echo "Printer Name: " & objPrinter.Name
If LCase(objPrinter.Name) = LCase(Sourceprt) Then
Wscript.Echo objPrinter.Name & " will be replaced by " & Destprt
'Install replacing printer:
objNetwork.AddWindowsPrinterConnection Destprt

'Check default printer:
Set WshShell = WScript.CreateObject("WScript.Shell")
strDefaultPrinter = WshShell.RegRead("HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\Windows\Device")
arrDefaultPrinter = Split(strDefaultPrinter, ",")

'Check if this is the default printer:
If LCase(arrDefaultPrinter(0)) = LCase(objPrinter.Name) Then
'Wscript.Echo "Is default printer"
'Set the printer as default:
objNetwork.SetDefaultPrinter Destprt
End If

'Remove old printer:
objNetwork.RemovePrinterConnection Sourceprt
End If

Next
Loop

]]> General http://jar.yosephine.com/index.php?itemid=10 Tue, 26 May 2009 05:49:48 -0400 http://jar.yosephine.com/index.php?itemid=8 Oh, and the password for the VNC session is "secret" (without the quotes). You can (and probably should) change it by editing the instantVNC.vbs script.

How to use:

1) Download this file.
2) Extract the content of the file to any desired folder on your PC.
3) Run the RUNME.BAT file

The script will ask for some details, such as the name or IP address of the computer you wish to remotely control. After this it will install the VNC service onto the target computer and launch the VNC client that will allow you to view and control the remote computer. This should work on Windows XP. Haven't tested in Vista, but probably won't work there.]]> General http://jar.yosephine.com/index.php?itemid=8 Mon, 25 May 2009 11:24:47 -0400 http://jar.yosephine.com/index.php?itemid=5
There are a number of things that could have been done better in this script. Now you can e.g. only search by exact file name, including extension (e.g. filename.exe) or substitute the file name or extension with wildcards (e.g. filename.* or *.exe). You're welcome to improve the script. If you decide to do so, please post the improved version here for everyone (including me) to enjoy.

Oh, and all scripts on this site (including this one) may be used by anyone for free, as long as you include the credits in the script code.

Well, enough babbling. Click on Read More to see the script.'ADFileFind.vbs by Dennis Nyholm (jar@yosephine.com) 16.7.2006

On Error Resume Next

Set strDomainName = "yourdomain"
Set strDomainExt = "net"

If Wscript.Arguments.Count < 1 Then
Wscript.Echo "Too few arguments!"& Chr(10) & Chr(13) & "Usage: cscript ADfilefind.vbs "
Wscript.Quit
End If

Set ArgObj = Wscript.Arguments
ArrFilename = split(ArgObj(0), ".")

Wscript.Echo "Filename=" & ArrFilename(0)
Wscript.Echo "Extension=" & ArrFilename(1)

Const ADS_SCOPE_SUBTREE = 2
Const MBCONVERSION= 1048576
Const ForReading = 1
Const ForWriting = 2

Set objConnection = CreateObject("ADODB.Connection")
Set objCommand = CreateObject("ADODB.Command")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"

Set objCOmmand.ActiveConnection = objConnection
objCommand.CommandText = "Select Name, Location from 'LDAP://DC=" & strDomainName & ",DC=" & strDomainExt & "' Where objectClass='computer'"
objCommand.Properties("Page Size") = 2000
objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
Set objRecordSet = objCommand.Execute
objRecordSet.MoveFirst
Err.Clear

Set FSO = CreateObject("Scripting.FileSystemObject")
Set objFile = FSO.CreateTextFile("Workfile.txt", True)
objFile.Close
Set objFile = FSO.OpenTextFile("Workfile.txt", ForWriting)


Do Until objRecordSet.EOF

objFile.WriteLine objRecordSet.Fields("Name").Value
objRecordSet.MoveNext
Loop
objFile.Close

Do
strCompsLeft = 0
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile("Workfile.txt", ForReading)

Set objFSO2 = CreateObject("Scripting.FileSystemObject")
Set objTextFile2 = objFSO2.CreateTextFile("Workfile2.txt", True)
objTextFile2.Close

Do Until objTextFile.AtEndOfStream
strComputer = objTextFile.Readline
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
If Err.Number = 0 Then
Wscript.Echo Chr(10) & Chr(13) & strComputer & ": "
If ArrFilename(0) = "*" Then
Set colFiles = objWMIService.ExecQuery ("Select * From CIM_DataFile Where Extension = '" & ArrFilename(1) & "'")
ElseIf ArrFilename(1) = "*" Then
Set colFiles = objWMIService.ExecQuery ("Select * From CIM_DataFile Where FileName = '" & ArrFilename(0) & "'")
Else
Set colFiles = objWMIService.ExecQuery ("Select * From CIM_DataFile Where FileName = '" & ArrFilename(0) & "' and Extension = '" & ArrFilename(1) & "'")
End If
For Each objFile in colFiles
Wscript.Echo objFile.Name
Next
Else
Set objTextFile2 = objFSO2.OpenTextFile("Workfile2.txt", ForWriting)
objTextFile2.WriteLine strComputer
obj.TextFile2.Close
Err.Clear
strCompsLeft = strCompsLeft + 1
End If
Loop
objTextFile.Close

objFSO.DeleteFile("Workfile.txt")

Set objFile = FSO.CreateTextFile("Workfile.txt", True)
objFile.Close
Set objFile = FSO.OpenTextFile("Workfile.txt", ForWriting)
Set objTextFile2 = objFSO2.OpenTextFile("Workfile2.txt", ForReading)
Do Until objTextFile2.AtEndOfStream
strTextLine = objTextFile2.Readline
objFile.WriteLine strTextLine
Loop
objFile.Close
objTextFile2.Close
Set objFSO = CreateObject("Scripting.FileSystemObject")
objFSO.DeleteFile("Workfile2.txt")
Wscript.Echo "Computers left: " & strCompsLeft
Loop]]> General http://jar.yosephine.com/index.php?itemid=5 Mon, 25 May 2009 10:20:02 -0400